Spis treści

# Funkcje macierzowe

W tej kategorii znajdują się funkcje macierzowe.

## Co to jest macierz?

Macierz jest połączonym zakresem komórek arkusza zawierającym wartości. Kwadratowy zakres komórek składający się z 3 wierszy i 3 kolumn jest nazywany macierzą 3 x 3:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

Najmniejszą możliwą macierzą jest macierz 1 x 2 lub 2 x 1 składająca się z dwóch przyległych komórek.

## Co to jest formuła macierzowa?

Formuła macierzowa to formuła, w której są obliczane poszczególne wartości w zakresie komórek. W odróżnieniu od innych formuł w formule macierzowej jednocześnie obliczana jest nie jedna, ale wiele wartości.

Formuła macierzowa nie tylko oblicza wiele wartości, ale może także zwracać wiele wyników. Wynikiem formuły macierzowej jest także macierz.

Aby pomnożyć wartości w poszczególnych komórkach przez 10 w powyższej macierzy, nie trzeba stosować formuły do każdej pojedynczej komórki lub wartości. Zamiast tego wystarczy użyć jednej formuły macierzowej. Zaznacz zakres komórek 3 x 3 w innej części arkusza kalkulacyjnego, wprowadź formułę =10*A1:C3 i potwierdź ten wpis za pomocą kombinacji klawiszy Command Ctrl + Shift + Enter. Wynikiem jest macierz 3 x 3, w której poszczególne wartości w zakresie komórek (A1:C3) są mnożone przez współczynnik 10.

W odwołaniu do zakresu (macierzy), oprócz mnożenia, można użyć także innych operatorów. Program LibreOffice Calc pozwala na korzystanie z operatorów dodawania (+), odejmowania (-), mnożenia (*), dzielenia (/), potęgowania (^), iloczynu logicznego (&) i porównania (=, <>, <, >, <=, >=). Operatory mogą służyć do obliczania poszczególnych wartości w zakresie komórek i w przypadku wprowadzenia formuły macierzowej zwracają wynik w postaci macierzy.

Podczas zmiany operatorów porównania w formule macierzowej puste komórki podlegają tym samym zasadom, co w przypadku pojedynczych porównań, czyli mogą być reprezentowane przez liczbę 0 lub ciąg pusty. W związku z tym obie formuły macierzowe: {=A1:A2=""} i {=A1:A2=0} zwracają 1-kolumnową i 2-wierszową macierz z komórkami zawierającymi wartość PRAWDA, jeśli komórki A1 i A2 są puste.

### Kiedy używa się formuł macierzowych?

Formuł macierzowych używa się w celu powtórzenia obliczeń dla różnych wartości. Późniejsza zmiana metody obliczeń wymaga jedynie aktualizacji formuły macierzowej. Aby dodać formułę macierzową, należy zaznaczyć cały zakres komórek, a następnie dokonać odpowiedniej zmiany w formule macierzowej.

W przypadku obliczania wielu wartości formuły macierzowe pozwalają także oszczędzić miejsce, ponieważ nie wymagają dużej ilości pamięci. Oprócz tego macierze są bardzo ważnym narzędziem w przypadku skomplikowanych obliczeń, ponieważ w obliczeniach można uwzględnić wiele zakresów komórek. Program LibreOffice posiada różne funkcje do przeprowadzania obliczeń na macierzach, miedzy innymi funkcję MACIERZ.ILOCZYN służącą do mnożenia dwóch macierzy i funkcję SUMA.ILOCZYNÓW obliczającą iloczyny skalarne dwóch macierzy.

## Korzystanie z formuł macierzowych w programie LibreOffice Calc

### Niejawne przecięcie formuł macierzy

Można również utworzyć „normalną” formułę, w której zakres odniesienia, taki jak parametry, wskazuje formułę macierzową. Ta formuła jest również znana jako „niejawne przecięcie” formuły macierzowej. Wynik uzyskuje się z przecięcia zakresu odniesienia i wierszy lub kolumn, w których znajduje się formuła. Jeśli nie ma przecięcia lub jeśli zakres na przecięciu obejmuje kilka wierszy lub kolumn, pojawia się komunikat o błędzie #ARG!. Poniższy przykład ilustruje tę koncepcję:

W powyższej tabeli umieść formułę macierzową w D1:

{=A1:A3 + 100}

Komórki D1, D2, D3 mają odpowiednio wartości 107, 195, 105.

Wstaw poniższą formułę w E2, nie wprowadzaj jej jako formuły macierzowej.

=A1:A3 + 100

Komórki E1 i E3 są puste, komórka E2 ma wartość 195. Jest to niejawne przecięcie formuł macierzowej.

Wstaw formułę poniżej w E4, tak jak w E2.

=A1:A3 + 100

Komórka E4 wyświetla #ARG!. Wiersz 4 jest poza zakresem A1:A3 formuły.

### Tworzenie formuł macierzowych

W przypadku tworzenia formuły macierzowej za pomocą Kreatora funkcji za każdym razem należy zaznaczyć pole wyboru Macierz, dzięki czemu wyniki są zwracane w postaci macierzy. W przeciwnym razie zostanie zwrócony wynik funkcji wyłącznie dla wartości w lewym górnym rogu macierzy.

Jeśli wprowadzasz formułę macierzową bezpośrednio do komórki, musisz użyć kombinacji klawiszy Shift + Command Ctrl + Enter zamiast klawisza Enter. Dopiero wtedy formuła staje się formułą macierzową.

Formuły macierzowe w programie LibreOffice Calc są wyświetlane w klamrach. Jednakże nie można utworzyć formuły macierzowej poprzez ręczne wprowadzenie klamer.

Komórki w macierzy wyników są automatycznie chronione przed zmianami. Możesz jednak edytować, usuwać lub kopiować formułę macierzową, zaznaczając cały zakres komórek macierzy.

### Korzystanie z wewnętrznych stałych macierzy w formułach

Program Calc obsługuje wewnętrzne stałe macierzowe/tablicowe w formułach. Wewnętrzna macierz znajduje się w nawiasach klamrowych '{' i '}'. Elementy mogą być liczbami (w tym liczbami ujemnymi), stałymi logicznymi (PRAWDA, FAŁSZ) lub ciągami literałów. Wyrażenia nie będące stałymi nie są dozwolone. Macierze mogą być wprowadzane w jednym lub kilku wierszach oraz w jednej lub kilku kolumnach. Wszystkie wiersze muszą składać się z tej samej liczby elementów, podobnie wszystkie kolumny muszą składać się z tej samej liczby elementów.

Separator kolumn (oddzielający elementy w jednym wierszu) i separator wierszy są zależne od ustawień regionalnych i języka. W pomocy użyto symbolu ';' średnika i '|' potoku jako separatora, odpowiednio kolumn i wierszy. Dla przykładu, w angielskich ustawieniach regionalnych przecinek ',' jest używany jako separator kolumn a średnik ';' jako separator wierszy.

Możesz przeglądać i zmieniać separator wierszy i kolumn w LibreOffice - Preferencje Narzędzia - Opcje - Calc - Formula - Separatory.

Macierze nie mogą być zagnieżdżone.

Przykłady:

={1;2;3}

Macierz składająca się z jednego wiersza zawierającego trzy liczby 1, 2 i 3.

Aby wprowadzić tę stałą macierzową, zaznacz trzy komórki z rzędu, a następnie wpisz formułę ={1;2;3} za pomocą nawiasów klamrowych i średników, a następnie naciśnij Command Ctrl + Shift + Enter.

={1;2;3|4;5;6}

Macierz składająca się z dwóch wierszy i trzech wartości w każdym wierszu.

={0;1;2|FAŁSZ;PRAWDA;"dwa"}

Mieszana macierz danych.

=SIN({1;2;3})

Wprowadzona jako formuła macierzowa zwraca wynik trzech obliczeń SIN z argumentami 1, 2 i 3.

### Edycja formuł macierzowych

1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową. Aby zaznaczyć całą macierz, umieść kursor na komórce w obszarze macierzy, a następnie naciśnij Command Ctrl + /, gdzie / to klawisz dzielenia na klawiaturze numerycznej.

2. Naciśnij F2 lub umieść kursor w wierszu wprowadzania. Obie te czynności umożliwiają edytowanie formuły.

3. Po wprowadzeniu zmian naciśnij Command Ctrl + Shift + Enter.

Części macierzy mogą być odrębnie formatowane, można na przykład zmienić kolor czcionki. W tym celu należy wybrać zakres komórek, a następnie zmienić żądany atrybut.

### Usuwanie formuł macierzowych

1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową. Aby zaznaczyć całą macierz, umieść kursor na komórce w obszarze macierzy, a następnie naciśnij Command Ctrl + /, gdzie / to klawisz dzielenia na klawiaturze numerycznej.

2. Naciśnij Delete, aby usunąć zawartość macierzy, w tym formułę macierzową, lub naciśnij Backspace, a to wywoła okno dialogowe Usuń zawartość. Wybierz Formuła lub Usuń wszystko i kliknij OK.

### Kopiowanie formuł macierzowych

1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową.

2. Naciśnij F2 lub umieść kursor w wierszu wprowadzania.

3. Skopiuj formułę do wiersza wprowadzania, naciskając Command Ctrl + C.

4. Zaznacz zakres komórek, w których chcesz wstawić formułę macierzową i naciśnij F2 lub umieść kursor w wierszu wprowadzania.

5. Wklej formułę, naciskając Command Ctrl + V w wybranym miejscu i potwierdź wciskając Command Ctrl + Shift + Enter. Wybrany zakres zawiera teraz formułę macierzową.

### Dostosowanie zakresu komórek

Aby edytować macierz wynikową, należy wykonać poniższe czynności:

1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową.

2. Poniżej zaznaczenia, po prawej stronie znajduje się mała ikona pozwalająca na zwiększenie lub zmniejszenie zakresu za pomocą myszy.

Dostosowanie zakresu macierzy nie powoduje dostosowania formuły macierzowej. Zmianie podlega wyłącznie zakres wyświetlanych wyników.

Przytrzymując Command Ctrl możesz utworzyć kopię formuły macierzowej w podanym zakresie.

### Warunkowe obliczenia macierzy

Warunkowe obliczenie macierzy jest macierzą lub formułą macierzową, która zawiera funkcję JEŻELI() lub WYBIERZ(). Argument warunkowy w formule jest odwołaniem do obszaru lub wynikiem macierzy.

W poniższym przykładzie zapis ">0" w formule {=JEŻELI(A1:A3>0;"tak";"nie")} dotyczy każdej komórki w zakresie A1:A3, a wynik jest kopiowany do odpowiedniej komórki.

| A | B (formuła) | B (wynik)
1 | 1 | {=JEŻELI(A1:A3>0;"tak";"nie")} | tak
2 | 0 | {=JEŻELI(A1:A3>0;"tak";"nie")} | nie
3 | 1 | {=JEŻELI(A1:A3>0;"tak";"nie")} | tak

Poniższe funkcje służą do wymuszonej obsługi macierzy: WSP.KORELACJI, KOWARIANCJA, REGLINX, TEST.F, ODCIĘTA, WYZNACZNIK MACIERZY, MACIERZ.ODW, MACIERZ.ILOCZYN, WYST.NAJCZĘŚCIEJ, PEARSON, PRAWDPD, R.KWADRAT, NACHYLENIE, REGBŁSTD, SUMA.ILOCZYNÓW, SUMA.X2.M.Y2, SUMA.X2.P.Y2, SUMA.XMY.2, TEST.T Użycie odwołań do obszarów jako argumentów powyższych funkcji powoduje, że zachowują się one jak funkcje macierzowe. Poniższa tabela przedstawia przykład wymuszonej obsługi macierzy:

| A | B (formuła) | B (wynik) | C (wymuszona formuła macierzowa) | C (wynik)
1 | 1 | =A1:A2+1 | 2 | =SUMA.ILOCZYNÓW(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMA.ILOCZYNÓW(A1:A2+1) | 5
3 |  | =A1:A2+1 | #ARG! | =SUMA.ILOCZYNÓW(A1:A2+1) | 5

## CZĘSTOŚĆ

Wskazuje rozkład częstotliwości w jednokolumnowej macierzy. Funkcja zlicza liczbę wartości w macierzy Dane, które mieszczą się w wartościach podanych przez macierz Klasy.

#### Składnia

CZĘSTOŚĆ(dane; klasy)

Dane określają macierz lub odwołanie do zestawu obliczanych wartości.

Klasy oznaczają macierz zestawu klas.

Ta funkcja ignoruje dowolny tekst lub puste komórki w zakresie danych. Jeśli podejrzewasz, że ta funkcja daje błędne wyniki, poszukaj tekstu w zakresach danych. Aby wyróżnić zawartość tekstową w zakresie danych, użyj funkcji wyróżniania wartości.

Ogólne wprowadzenie do kategorii funkcji Macierz można znaleźć na górze tej strony.

#### Przykład

W poniższej tabeli kolumna A zawiera nieposortowane wyniki pomiarów. Kolumna B zawiera górne granice poszczególnych klas, na które należy podzielić kolumnę A. Zgodnie z granicą określoną w komórce B1 funkcja CZĘSTOŚĆ zwraca liczbę wartości pomiarów mniejszych lub równych 5. Granica w komórce B2 wynosi 10, w związku z czym funkcja CZĘSTOŚĆ zwraca drugi wynik oznaczający liczbę wartości pomiarów większych od 5 lub większych lub równych 10. Tekst ">25" wprowadzony w komórce B6 ma znaczenie wyłącznie informacyjne.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Zaznacz zakres obejmujący pojedynczą kolumnę, w której należy wprowadzić częstość wartości, które są większe od górnej granicy klasy. Należy zaznaczyć o jedno pole więcej niż górna granica klasy. W odniesieniu do tego przykładu zaznacz zakres C1:C6. W Kreatorze funkcji wybierz funkcję CZĘSTOŚĆ. Zaznacz zakres wyników pomiarów (A1:A11) jako parametr Dane, a następnie zaznacz kolumnę Klasy zawierającą granice klas (B1:B6). Zaznacz pole wyboru Macierz i kliknij przycisk OK. We wstępnie zaznaczonym zakresie C1:C6 zostaną wyświetlone wyniki funkcji częstości.

Więcej wyjaśnień na górze tej strony.

## JEDN.MACIERZY

Zwraca kwadratową macierz unitarną określonego rozmiaru. Macierz unitarna jest macierzą kwadratową o elementach na głównej przekątnej równych 1 i wszystkich pozostałych elementach równych 0.

#### Składnia

JEDN.MACIERZY(wymiary)

Wymiary oznaczają rozmiar jednostki macierzy.

Ogólne wprowadzenie do kategorii funkcji Macierz można znaleźć na górze tej strony.

#### Przykład

Zaznacz kwadratowy obszar na arkuszu, na przykład od A1 do E5.

Bez usuwania zaznaczenia wybierz funkcję JEDN.MACIERZY. Zaznacz pole wyboru Macierz. Wprowadź żądane wymiary jednostki macierzy, w tym przypadku 5, a następnie kliknij przycisk OK.

Możesz także wpisać formułę =JEDN.MACIERZY(5) w ostatniej komórce zaznaczonego zakresu (E5) i nacisnąć Shift + Command + Enter Shift + Ctrl + Enter.

W zakresie A1:E5 zostanie utworzona macierz unitarna.

Więcej wyjaśnień na górze tej strony.

## MACIERZ.ILOCZYN

Wyznacza iloczyn dwóch macierzy. Liczba kolumn pierwszej macierzy musi być równa liczbie wierszy drugiej macierzy. Macierz kwadratowa charakteryzuje się równą liczbą wierszy i kolumn.

#### Składnia

MACIERZ.ILOCZYN(macierz 1; macierz 2)

Macierz 1 reprezentuje pierwszą macierz używaną w iloczynie macierzy.

Macierz 2 reprezentuje drugą macierz z taką samą liczbą wierszy.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Wybierz kwadratowy obszar komórek. Wybierz funkcję MACIERZ.ILOCZYN. Wprowadź Macierz 1, a następnie Macierz 2. W Kreatorze funkcji zaznacz pole Macierz. Kliknij przycisk OK. Otrzymana macierz jest wyświetlana w zakresie komórek wybranych w pierwszym kroku.

## MACIERZ.ODW

Zwraca macierz odwrotną.

#### Składnia

MACIERZ.ODW(macierz)

Macierz oznacza macierz kwadratową, którą należy odwrócić.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Zaznacz macierz, a następnie wybierz funkcję MACIERZ.ODW. Zaznacz macierz wyjściową, zaznacz pole Macierz, a następnie kliknij przycisk OK.

## REGEXPP

Funkcja wyznacza dopasowanie wprowadzonych danych w postaci wykładniczej krzywej regresji (y=b*m^x).

#### Składnia

REGEXPP(dane_Y [; dane_X [; typ_funkcji [; parametry]]])

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Typ_funkcji (parametr opcjonalny). Jeśli typ_funkcji = 0, zostanie obliczona funkcja w formie y = m^x. W przeciwnym razie zostaną obliczone funkcje y = b*m^x.

Parametry (parametr opcjonalny). Jeśli parametr=0, zostanie obliczony wyłącznie współczynnik regresji.

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Zobacz REGLINP. Suma kwadratów nie zostanie jednak obliczona.

## REGEXPW

Wyznacza punkty regresji wykładniczej w macierzy.

#### Składnia

REGEXPW(dane_Y[; [ dane_X ] [; [ nowe_dane_X ] [; typ_funkcji ] ] ])

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Nowe_dane_X (parametr opcjonalny) oznaczają macierz danych X używanych do ponownego obliczenia wartości.

Typ_funkcji (parametr opcjonalny). Jeśli Typ_funkcji = 0, zostaną obliczone funkcje w postaci y = m^x. W przeciwnym razie zostaną obliczone funkcje y = b*m^x.

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Ta funkcja zwraca macierz i jest obsługiwana w taki sam sposób, jak inne funkcje macierzowe. Wybierz zakres, w którym mają się pojawić odpowiedzi, i wybierz funkcję. Wybierz Dane_Y. Wprowadź inne parametry, zaznacz Macierz i kliknij OK.

## REGLINP

Zwraca tabelę ze statystykami prostej linii, która najlepiej pasuje do zestawu danych.

#### Składnia

REGLINP(dane_Y [; dane_X [; typ_liniowy [; parametry]]])

Dane_Y to pojedynczy wiersz lub kolumna z danymi określającymi współrzędne Y w zestawie punktów danych.

Dane_X to odpowiadający pojedynczy wiersz lub kolumna z danymi określającymi współrzędne X w zestawie punktów danych. Jeżeli argumentdane_X zostanie pominięty, arkusz przyjmie domyślne wartości 1, 2, 3, ..., n. Jeżeli dostępnych jest kilka zestawów zmiennych, argument dane_X może być zakresem z wieloma odpowiadającymi wierszami lub kolumnami.

Funkcja REGLINP odnajduje prostą wyrażoną wzorem y = a + bx, która najdokładniej pasuje do danych. W tym celu wykorzystuje mechanizm regresji liniowej (metodę "najmniejszych kwadratów"). W przypadku kilku zestawów zmiennych prosta wyrażona jest wzorem y = a + bx1 + bx2 ... + bnxn.

Jeżeli argument typ_liniowy przyjmie wartość FAŁSZ, spowoduje to wymuszenie przejścia znalezionej prostej przez początek układu współrzędnych (stała a przyjmie wartość zero; prosta będzie wyrażona wzorem y = bx). Jeżeli argument typ_liniowy zostanie pominięty, przyjmie on domyślną wartość PRAWDA (nie będzie wymuszenia przejścia przez początek układu współrzędnych).

Jeżeli argument parametry zostanie pominięty lub przyjmie wartość FAŁSZ, zostanie zwrócony jedynie górny wiersz tabeli ze statystyką. Jeżeli argument ten przyjmie wartość PRAWDA, zostanie zwrócona cała tabela.

REGLINP zwraca tabelę (macierz) statystyk jak poniżej i musi być wprowadzona jako formuła macierzowa (na przykład za pomocą Command Ctrl + Shift + Return zamiast tylko Return).

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Funkcja ta zwraca macierz i obsługiwana jest w taki sam sposób, w jaki obsługiwane są pozostałe funkcje macierzowe. Zaznacz obszar odpowiedzi, a następnie funkcji. Zaznacz obszar argumentu dane_Y. W razie potrzeby możesz wprowadzić pozostałe argumenty. Zaznacz pole wyboru Macierz, a następnie kliknij przycisk OK.

Wartości zwrócone przez program (przy argumencie parametry = 0) pokażą przynajmniej nachylenie krzywej regresji i jej punkt przecięcia z osią Y. Jeżeli argument parametry ma wartość inną niż 0, zostaną wyświetlone inne wyniki.

### Pozostałe wyniki funkcji REGLINP:

Przykłady:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | Wartość REGLINP |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #BRAK
5 | 7 | 12 | 108 |  | 13,21 | 4 | #BRAK
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #BRAK
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Kolumna A zawiera kilka wartości X1, kolumna B zawiera wartości X2, a kolumna C - wartości Y. Powyższe wartości już zostały wprowadzone do arkusza kalkulacyjnego. Zaznacz zakres E2:G6 i uruchom Kreatora funkcji. W celu wprowadzenia funkcji REGLINP należy zaznaczyć pole wyboru Macierz w Kreatorze funkcji. Następnie zaznacz na arkuszu kalkulacyjnym następujące wartości (lub wprowadź je za pomocą klawiatury):

Dane_Y to C2:C8

Dane_X to A2:B8

Typ_liniowy oraz parametry ustawione na wartość 1.

Po kliknięciu przycisku OK program LibreOffice Calc wypełnia powyższą tabelę przedstawionymi w niej wartościami funkcji REGLINP.

Formuła na pasku Formuła odpowiada każdej komórce macierzy REGLINP {=REGLINP(C2:C8;A2:B8;1;1)}.

Znaczenie obliczonych wartości funkcji REGLINP jest następujące:

E2 i F2: Nachylenie m krzywej regresji y=b+m*x dla wartości x1 i x2. Wartości są podane w odwrotnej kolejności, wartość E2 oznacza nachylenie dla x2, a F2 dla x1.

G2: Przecięcie b z osią y.

E3 i F3: Błąd standardowy wartości nachylenia.

G3: Błąd standardowy przecięcia

E4: R.KWADRAT

F4: Błąd standardowy regresji obliczonej z wartości Y.

E5: Wartość F obliczona na podstawie analizy wariancji.

F5: Stopień swobody obliczony na podstawie analizy wariancji.

E6: Suma kwadratów odchyleń wartości Y obliczonych na podstawie ich średniej liniowej.

F6: Suma kwadratów odchyleń wartości Y obliczonej na podstawie podanych wartości Y.

Więcej wyjaśnień na górze tej strony.

## REGLINW

Zwraca wartości regresji liniowej.

#### Składnia

REGLINW(dane_Y [; dane_X [; nowe_dane_X [; typ_liniowy]]])

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Nowe_dane_X (parametr opcjonalny) oznaczają macierz danych X używanych do ponownego obliczenia wartości.

Typ_liniowy (parametr opcjonalny). Jeśli Typ_liniowy = 0, linie zostaną obliczone przez punkt zerowy. W przeciwnym razie zostaną również obliczone linie odsunięcia. Wartość domyślna to Typ_liniowy <> 0.

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

Więcej wyjaśnień na górze tej strony.

#### Przykład

Wybierz zakres arkusza kalkulacyjnego, w którym pojawią się dane trendu. Wybierz funkcję. Wprowadź dane wyjściowe lub zaznacz je myszką. Zaznacz pole Macierz, kliknij OK. Wyświetlane są dane trendu obliczone na podstawie danych wyjściowych.

## SUMA.ILOCZYNÓW

Mnoży odpowiadające sobie elementy w podanych macierzach i zwraca sumę tych iloczynów.

#### Składnia

SUMA.ILOCZYNÓW(macierz 1[; macierz 2;][...;[macierz 255]])

Macierz 1[; Macierz 2;][...;[Macierz 255]] reprezentuje macierze, których odpowiednie elementy mają zostać pomnożone.

Co najmniej jedna macierz musi być częścią listy argumentów. Jeśli podana jest tylko jedna macierz, wszystkie elementy macierzy są sumowane. Jeśli podano więcej niż jedną macierz, wszystkie muszą mieć ten sam rozmiar.

#### Przykład

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMA.ILOCZYNÓW(A1:B3;C1:D3) zwraca wartość 397.

Obliczenia: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Funkcja SUMA.ILOCZYNÓW pozwala na obliczenie iloczynu skalarnego dwóch wektorów.

Funkcja SUMA.ILOCZYNÓW zwraca jedną liczbę, nie ma potrzeby wprowadzania jej w postaci funkcji macierzowej.

Więcej wyjaśnień na górze tej strony.

## SUMA.X2.M.Y2

Zwraca sumę różnic kwadratów odpowiadających sobie wartości dwóch macierzy.

#### Składnia

SUMA.X2.M.Y2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być podniesione do kwadratu i dodane.

Macierz_Y oznacza drugą macierz, której elementy mają być podniesione do kwadratu i odjęte.

Więcej wyjaśnień na górze tej strony.

## SUMA.X2.P.Y2

Zwraca sumę sum kwadratów odpowiadających sobie wartości dwóch macierzy.

#### Składnia

SUMA.X2.P.Y2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być podniesione do kwadratu i dodane.

Macierz_Y oznacza drugą macierz, której elementy mają być podniesione do kwadratu i dodane.

Więcej wyjaśnień na górze tej strony.

## SUMA.XMY.2

Dodaje kwadraty wariancji pomiędzy odpowiadającymi sobie elementami dwóch macierzy.

#### Składnia

SUMA.XMY.2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być odjęte i podniesione do kwadratu.

Macierz_Y oznacza drugą macierz, której elementy mają być odjęte i podniesione do kwadratu.

Więcej wyjaśnień na górze tej strony.

## TRANSPONUJ

Transponuje wiersze macierzy z jej kolumnami.

#### Składnia

TRANSPONUJ(macierz)

Macierz oznacza macierz, którą należy przetransponować.

Ogólne wprowadzenie do kategorii funkcji Macierz znajduje się na górze tej strony.

#### Przykład

Wybierz zakres komórek w akruszu, w których pojawi się transponowana macierz. Jeśli oryginalna macierz ma n wierszy i m kolumn, wybrany zakres komórek musi mieć co najmniej n kolumn i m wierszy. Następnie wprowadź formułę bezpośrednio, wybierz macierz źródłową i naciśnij Shift+Command+Enter Shift+ Ctrl+Enter. Jeśli używasz Kreator funkcji, pamiętaj o zaznaczeniu pola Macierz. Transponowana macierz pojawia się w docelowym obszarze komórek i jest automatycznie chroniona przed zmianami.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

Powyższa tabela zawiera 2 wiersze, 4 kolumny. W celu dokonania transpozycji należy wybrać 4 wiersze, 2 kolumny. Zakładając, że chcemy przenieść powyższą tabelę do zakresu A7:B10 (4 rzędy, 2 kolumny), należy wybrać cały zakres, a następnie wprowadzić następujące elementy:

TRANSPONUJ(A1:D2)

Upewnij się, że wprowadzasz formułę macierzową za pomocą Shift+Command+Enter Shift+Ctrl+Enter. Wynik będzie następujący:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

## WYZNACZNIK.MACIERZY

Zwraca wyznacznik macierzy. Funkcja zwraca wartość w bieżącej komórce; nie jest wymagane zdefiniowanie zakresu.

#### Składnia

WYZNACZNIK.MACIERZY(macierz)

Macierz oznacza macierz kwadratową, dla której należy obliczyć wyznacznik.

Ogólne wprowadzenie do kategorii funkcji Macierz znajduje się na górze tej strony.

Więcej wyjaśnień na górze tej strony.

Tematy pokrewne

Funkcje według kategorii